Can all structurally recursive functions be written without explicit recursion using a catamorphism/fold?

Question

In particular, I am thinking of a function which involves conditionals changing the recursive behavior and multiple F-algebras.

halting_search :: int -> (a -> bool) -> (a -> a) -> a -> Maybe a
halting_search 0 f_test f_next_candidate candidate = Nothing
halting_search (S n) f_test f_next_candidate candidate = case (f_test candidate) of
  true => Just candidate
  false => halting_search n f_test f_next_candidate (f_next_candidate candidate)

Is this capable of being written just using the cata operator? The reason I'm asking is because I want a functional language that is fairly expressive but not overly expressive, and it seems like one way to do that might be to not allow explicit recursion but make cata a primitive function.

Answer 1

Your function is completely structurally recursive on n, so it is pretty much just a change of notation to make it a catamorphism on the natural numbers.

type nat = Z | S of nat 

(* cata : α → (α → α) → nat → α *)                      
let rec cata z s = function
  | Z -> z 
  | S n -> s (cata z s n)

(* halting_search : nat → (α → bool) → (α → α) → α → α option *)             
let halting_search n = 
  cata (fun test next seed -> None)
       (fun recur test next seed -> 
         if test seed then 
           Some seed
         else 
           recur test next (next seed))
       n

For languages with higher-order functions and strictly positive datatypes, having a fold is equivalent in expressive power to permitting structural recursion. However, it is not equivalent in terms of efficiency. If you just have fold, then implementing the predecessor function on the Peano natural numbers is O(n), whereas if you have a case form, it is O(1).

(* This is linear time! *)
pred : nat -> nat option 
let pred n = cata None (function 
                           | None   -> Some Z 
                           | Some n -> Some (S n)) n